#include <PWM.h>

// ピン構成
int pin = 9;          // ピン
int value = 127;      // PWM デューティサイクルの初期値
float frequency = 60; // 初期周波数(Hz)

void setup()
{
    Serial.begin(9600);

    // 時間計測タスクを保護するため、timer0 以外のすべてのタイマーを初期化
    InitTimersSafe();

    // 初期 PWM 周波数とデューティサイクルを設定
    if (SetPinFrequencySafe(pin, frequency))
    {
        pwmWrite(pin, value);
        Serial.println("PWM frequency and initial duty cycle set.");
    }
    else
    {
        Serial.println("Failed to set frequency.");
    }
}

void loop()
{
    if (Serial.available())
    {
        // Serial から周波数とデューティサイクル値を読み取る
        String inputString = Serial.readStringUntil('\n'); 
        inputString.trim();                                
        int freqDutySplitIndex = inputString.indexOf(',');

        if (freqDutySplitIndex != -1)
        {
            String freqStr = inputString.substring(0, freqDutySplitIndex);  
            String dutyStr = inputString.substring(freqDutySplitIndex + 1); 

            // float をパース
            float newFrequency = freqStr.toFloat();
            int newDutyCycle = dutyStr.toInt();

            // 周波数範囲を検証
            if (newFrequency >= 1 && newFrequency <= 2000000)
            {
                // PWM 周波数を設定し、デューティサイクルを適用
                if (SetPinFrequencySafe(pin, newFrequency))
                {
                    value = map(constrain(newDutyCycle, 0, 100), 0, 100, 0, 255);
                    pwmWrite(pin, value);
                    Serial.print("Set frequency to: ");
                    Serial.print(newFrequency);
                    Serial.print(" Hz, duty cycle to: ");
                    Serial.print(newDutyCycle);
                    Serial.println("%");
                }
                else
                {
                    Serial.println("Failed to set new frequency.");
                }
            }
            else
            {
                Serial.println("Invalid frequency value.");
            }
        }
        else
        {
            Serial.println("Invalid input format. Use frequency,dutycycle (e.g., 60,50).");
        }
    }
}